verbatimtex
%&latex
\documentclass{article}
\usepackage{amsmath}
\begin{document}
etex

beginfig (1);

%% ICMP 2003 logo
%% by jmce@artenumerica.com, June 2001

picture MF;
MF = thelabel.urt (btex {\Huge\hspace{1em}$\mathbf{M}\boldsymbol{\cap}\boldsymbol{\Phi}$\hspace{1em}} etex, (0,0));

z.c = center bbox MF;
z.a = llcorner bbox MF;
z.e = urcorner bbox MF;

g := (sqrt 5 - 1)/2;

numeric widMF, heiMF;
widMF = x.e - x.a;
heiMF = y.e - y.a;


picture ICMP;
ICMP = thelabel.urt (btex {\Large \textsl{ICMP 2003}} etex, (x.a, y.a+2*g*heiMF));
picture LX;
LX = thelabel.llft (btex {\Large \textsl{Lisbon}} etex, (x.e, y.e-2*g*heiMF));

path ellipse;
ellipse = fullcircle xscaled (widMF) yscaled (g * widMF) shifted z.c;

pen epen;
epen := pencircle xscaled 4bp yscaled 1bp rotated 23.45; 
% (23.45 degrees is the Earth rotation axis obliquity)
color ecolor;
ecolor := (0.82, 0.25, 0);

draw MF;
draw ICMP;
draw LX;

linecap := butt;
draw ellipse 
  cutafter ((ulcorner bbox ICMP--urcorner bbox ICMP) shifted (0,1pt))
withpen epen withcolor ecolor;
draw ellipse 
  cutbefore ((llcorner bbox ICMP--lrcorner bbox ICMP) shifted (0,-1pt))
  cutafter ((llcorner bbox LX--lrcorner bbox LX) shifted (0,-1pt))
withpen epen withcolor ecolor;
draw ellipse 
  cutbefore ((ulcorner bbox LX--urcorner bbox LX) shifted (0,-2pt))
withpen epen withcolor ecolor;

endfig;

verbatimtex
\end{document}
etex

end